К содержанию
Кодумкаподготовка к ЕГЭ по информатике
Проверяем вход
Меню

Подтема 2 из 6

Таблица в Excel

Как записать правило клетки формулами: блок под полем, четыре формулы и замена МАКС на МИН.

Расчётный блок

Где в Excel считать лучшие суммы?

Под полем, в блоке той же формы: каждой клетке поля соответствует своя клетка блока. Поле 4 × 4 занимает A1:D4. Оставим пустую строку 5, и блок наибольших сумм займёт A6:D9: клетке B2 поля соответствует B7 блока — ровно на 5 строк ниже.

Блок ставят под полем, а не справа: на экзамене поле широкое, а вниз места сколько угодно.

Четыре формулы

Какие формулы записать в блок?

Хватит четырёх: для старта, верхней строки, левого столбца и одной внутренней клетки. Остальное заполнит .

A6=A1
B6=A6+B1
A7=A6+A2
B7=B2+МАКС(A7;B6)
  • A6 — старт: монета A1, 2.
  • B6 — верхняя строка: сумма слева плюс монета, 2 + 7 = 9. Растягиваем вправо до D6.
  • A7 — левый столбец: сумма сверху плюс монета. Растягиваем вниз до A9.
  • B7 — монета B2 плюс большая из сумм слева (A7) и сверху (B6): 1 + 9 = 10. Растягиваем на весь B7:D9.

В D9, под финишем D4, получится 35 — как и руками.

Почему одна формула подходит всем

Почему одну и ту же формулу можно растянуть на весь блок?

При копировании ссылки сдвигаются вместе с формулой, и смысл сохраняется: «моя монета плюс лучшая из сумм слева и сверху». Такие ссылки называют . Копии формулы из B7 на клетку вправо и на клетку вниз:

B7=B2+МАКС(A7;B6)
C7=C2+МАКС(B7;C6)
B8=B3+МАКС(A8;B7)
Тонкости:знак $

Знак $ закрепляет адрес. Здесь он только мешает: если написать $B$2, все клетки блока будут прибавлять одну и ту же монету из B2, и в D9 вместо 35 получится 17.

Минимум

А как получить наименьшую сумму?

Так же, только с МИН. Проще всего записать максимум и заменить МАКС на МИН в блоке командой «Найти и заменить» (CtrlH). Блок пересчитается, и в D9 появится минимум. Можно и построить второй блок ниже, в A11:D14, — в листе ниже оба блока. Поменяй любую монету: пересчитаются оба.

B12=B2+МИН(A12;B11)
ABCD
12741
25183
32629
44372
5
6291314
77102124
89162333
913193035
10
11291314
12781617
139141625
1413162325
Формулы в ячейках
  • A6=A1
  • A7скопирована до A9=A6+A2
  • A11=A1
  • A12скопирована до A14=A11+A2
  • B6скопирована до D6=A6+B1
  • B7скопирована до D9=B2+МАКС(A7;B6)
  • B11скопирована до D11=A11+B1
  • B12скопирована до D14=B2+МИН(A12;B11)

Ответы — в D9 и D14: 35 и 25. Выбери C13 — рамки покажут монету C3 поля и двух соседей в блоке минимума.

Тонкости:почему нельзя скопировать готовый блок

Если скопировать A6:D9 целиком в A11:D14, сдвинутся и ссылки на монеты: в B12 окажется =B7+МАКС(A12;B11), и вместо монеты 1 из B2 прибавится 10 из блока максимума. Поэтому второй блок строят теми же четырьмя формулами, а замена МАКС на МИН внутри блока ссылки не трогает.

Поле из файла

Что меняется на поле экзамена?

Только адреса: те же четыре формулы, блок под полем через пустую строку. Поле задачи темы — 20 × 20, оно занимает A1:T20. Блок начнём со строки 22:

A22=A1
B22=A22+B1
A23=A22+A2
B23=B2+МАКС(A23;B22)

B22 растягивают вправо до T22, A23 — вниз до A41, а B23 — на весь прямоугольник B23:T41. Большой диапазон удобно выделить, вписав его адрес в слева от строки формул. Лучшая сумма до правой нижней клетки — в T41.

После растягивания открой две-три формулы — первую внутреннюю, из середины и последнюю — и проверь, что они ссылаются на свою монету и на соседей слева и сверху. Ответ записывай в том порядке, который требует условие: у нас — сначала максимум, потом минимум, через пробел.

Итого

  • Блокпод полем через пустую строку, той же формы
  • Старт=A1
  • Края=A6+B1 вправо, =A6+A2 вниз
  • Внутри=B2+МАКС(A7;B6) на весь блок
  • Минимумзамена МАКС на МИН (CtrlH) или второй блок
  • Ответв клетке блока под финишем, в порядке условия

Проверьте себя

Ответь сначала сам, потом открой ответ.

Вопрос 1
Формулу =B2+МАКС(A7;B6) растянули на B7:D9. Какая формула окажется в C8?
ОтветСкрыть ответ
Ответ
=C3+МАКС(B8;C7): монета C3 и суммы соседей слева и сверху в блоке.
Вопрос 2
В B6 записали =B1. Что не так?
ОтветСкрыть ответ
Ответ
Пропала сумма до соседа слева: получился маршрут, который начался в B1. Нужно =A6+B1.
Вопрос 3
Что получится, если в формуле написать $B$2 вместо B2 и растянуть её на весь блок?
ОтветСкрыть ответ
Ответ
Все клетки блока будут прибавлять одну и ту же монету из B2, а не свою. Здесь ссылки должны сдвигаться вместе с формулой.
Вопрос 4
Блок максимума A6:D9 скопировали целиком в A11:D14. Какая формула окажется в B12 и что в ней не так?
ОтветСкрыть ответ
Ответ
=B7+МАКС(A12;B11): вместо монеты из B2 она берёт число из блока максимума.
Вопрос 5
Поле 20 × 20 занимает A1:T20, блок начинается в A22. В какой ячейке будет лучшая сумма до правой нижней клетки?
ОтветСкрыть ответ
Ответ
В T41: блок сдвинут на 21 строку вниз, а T20 + 21 строка = T41.

Практика

Для проверки ответов нужен JavaScript. Условия, подсказки и решения доступны ниже.

Поле 15 × 15

Поле в файле 18-1.xlsx — квадрат 15 × 15. Робот начинает в левой верхней клетке и ходит вправо или вниз. Определите максимальную и минимальную денежные суммы, которые он может собрать, пройдя в правую нижнюю клетку.

18-1.xlsxПоле — Excel-файл, как на экзаменеExcel · 5,9 КБ

Введите через пробел максимальную сумму, затем минимальную.

Финиш в J10

Для того же поля 18-1.xlsx определите максимальную и минимальную суммы, если маршрут заканчивается в клетке J10.

18-1.xlsxПоле — Excel-файл, как на экзаменеExcel · 5,9 КБ

Введите через пробел минимальную сумму, затем максимальную.